HowTo: Set up MTW2 for modding

[NorseFury]

I'm new to modding, I was wondering if you can unpack with v 1.3, or do I have to have 1.1?

[camren shea]

ok i loaded the thing that changes the the files to txt files but this guild said directions for the for the download are supposed to be on the readme I can't find that readme can someone please tell where that is.

[TheRagMan]

Hi all, I'm new here and used all the data here to set up my mod environment .

Here's my contribution, as a token of my gratitude .

It's a batch file you can run from anywhere on your computer, all you have to do is to write the full path to your M2TW install location where indicated .

:: turn off echoing back of commands
@echo off

:: clear the screen
cls

:: You MUST write after the = mark the full path to your own M2TW
:: install location
set M2TW=C:\Program Files\SEGA\Medieval II Total War\

:: Don't modify those variables unless you really know what you're doing
set UNPACKER=%M2TW%\tools\unpacker
set DEST=%M2TW%backup\
set MAPS=%M2TW%data\world\maps\
set DESTBASE=%DEST%data\world\maps\base
set DESTCAMP=%DEST%data\world\maps\campaign\imperial_campaign

:: This will show you which directories are used before going on
echo M2TW install location: %M2TW%
echo Source of backup: %MAPS%
echo Backup of base location: %DESTBASE%
echo Backup of campaign location: %DESTCAMP%
echo Destination of unpacked files: %DEST%
pause

:: This creates destination directories
mkdir "%DESTCAMP%"
mkdir "%DESTBASE%"

:: This copies contents from the map directory and saves it to destination
xcopy "%MAPS%base" "%DESTBASE%" /s /e
xcopy "%MAPS%campaign\imperial_campaign" "%DESTCAMP%" /s /e

:: This actually unpacks the files to your destination backup location
chdir /d "%UNPACKER%"
unpacker.exe --source=..\..\packs\localized.pack --destination=..\..\backup –verbosity=1

:: This performs the mandatory renaming of descr_geography* files
move "%DEST%data\descr_geography_new.db" "%DEST%data\descr_geography_new.db.back"
move "%DEST%data\descr_geography_new.txt" "%DEST%data\descr_geography_new.txt.back"

:: A little pause so you can read the results
pause

Thanks.