Edit 5: I've made a .bat that swaps the EDUs as needed and can start the game automatically.
It currently lets you choose between 6 options:
configure EB for campaign
configure EB for campaign and start EB
configure EB for custom battles or multiplayer
configure EB for custom battles or multiplayer and start EB
exit and start EB
exit without starting EB
Some caveats:
- EB 0.81a hotfix changes the "\EB\Data\export_descr_unit.txt" file but does not update the custommp or backup EDUs so don't use this with 0.81a until they are updated
- It requires to be put in the "installpath\EB\" directory.
- Because DOS doesn't like spaces in directory names (and/or I just don't know how to make a .bat to bypass the issue):
You must rename the folders "\mp custom game edu\" and "\sp game edu backup\"
to "\mp_custom_game_edu\" and "\sp_game_edu_backup\"
- There are 2 custom/mp text files in the relevant directory, I'm not sure which is supposed to be used?:
export_descr_unit_custommp.txt 362kb
export_descr_unit_mpcustom.txt 361kb
This code uses the export_descr_unit_custommp.txt but its an easy fix if it should be the other. - If someone could provide example files, I could alter it to change the menus so you can't accidentally load your campaign & break it because you used the custom battle/mp EDU...
You can change your icon to point to the .bat instead of the RomeTW.exe if you don't want to browse to the folder all the time.
So to the code:
Code:
@echo off
rem -EDU swapper MK1.6 by Hoom 4/3/07
rem -intended for use on Windows XP, not sure if it works on other windows versions
rem -feel free to use and alter as needed, its a very basic .bat file...
rem -Note: this file presumes it is placed in the \EB directory!
rem -menu
:menu
rem -options
echo.
echo =================EDU swapper=================
echo 1 to configure EB for campaign
echo 2 to configure EB for campaign and start EB
echo 3 to configure EB for custom battles or multiplayer
echo 4 to configure EB for custom battles or multiplayer and start EB
echo 5 to exit and start EB
echo 6 to exit without starting EB
echo.
rem -the choice code
set choice=
set /p choice=choose an option:
rem if not '%choice%'=='' set choice=%choice:~0,1%
if '%choice%'=='1' goto campaign
if '%choice%'=='2' goto campaignstart
if '%choice%'=='3' goto custommp
if '%choice%'=='4' goto custommpstart
if '%choice%'=='5' goto endstart
if '%choice%'=='6' goto end
echo '%choice%' is not valid, please try again
echo choose a number 1 to 6:
goto menu
rem -set for campaign EDU
:campaign
cls
echo.
echo You chose to configure EB for campaign
echo.
@echo on
copy .\sp_game_edu_backup\export_descr_unit.txt .\Data\export_descr_unit.txt
@echo off
echo.
echo EB is now configured for campaign
goto menu
rem -set for campaign EDU & start EB
:campaignstart
cls
echo You chose to configure EB for campaign then start EB
echo.
@echo on
copy .\sp_game_edu_backup\export_descr_unit.txt .\Data\export_descr_unit.txt
@echo off
goto endstart
rem -set for custommp EDU
:custommp
cls
echo.
echo You chose to configure EB for custom battles or multiplayer
echo.
@echo on
copy .\mp_custom_game_edu\export_descr_unit_custommp.txt .\Data\export_descr_unit.txt
@echo off
echo.
echo EB is now configured for custom battle and multiplayer
goto menu
rem -set for custommp EDU & start EB
:custommpstart
cls
echo You chose to configure EB for campaign then start EB
echo.
@echo on
copy .\mp_custom_game_edu\export_descr_unit_custommp.txt .\Data\export_descr_unit.txt
@echo off
goto endstart
rem -endstart
:endstart
cls
echo.
echo Now starting EB
rem -start EB
cd..
start .\RomeTW.exe -mod:eb -nm -show_err
exit
rem -end without starting EB
:end
cls
echo.
echo You chose to exit without starting EB
pause
exit
Re: Custom Battle Roster?
Originally Posted by Thaatu
Posting Permissions
Reply With Quote
Bookmarks